I found myself wanting to automatically keep a log of every org-roam entry I work on. After struggling with the capture system for a while, I managed to make something work.
(setf (alist-get "u" org-roam-dailies-capture-templates nil nil #'equal)
'("updated" plain nil
:target (file+head+olp "%<%Y-%m-%d>.org" "#+title: %<%Y-%m-%d>\n" ("Updated"))
:unnarrowed t :prepend t))
(defmacro +save-current-buffer (&rest body)
"Save current buffer; execute BODY; restore original buffer.
I have found that this macro works under some circumstances in
which ‘save-current-buffer’ does not."
(declare (indent 0))
`(let ((original-buffer (current-buffer)))
(unwind-protect (progn ,@body)
(when (buffer-name original-buffer)
(switch-to-buffer original-buffer)))))
(defmacro +edit-to-string (&rest body)
"Eval BODY in a temporary buffer and extract contents to a string."
(declare (indent 0))
`(with-temp-buffer
,@body
(buffer-string)))
(defun +org-element-contents (element)
"Extract contents of ELEMENT from current buffer."
(buffer-substring (org-element-property :contents-begin element)
(org-element-property :contents-end element)))
(defun +org-roam-updated-on-save ()
"Log current Org-roam buffer as modified."
(when (org-roam-buffer-p)
(let* ((original-buffer (current-buffer))
(id (org-id-get (point-min)))
(title (org-get-title))
(link-text (format "%s\n" (+edit-to-string
(org-insert-link nil id title)))))
(save-excursion ;; in case we are currently editing the daily note
(+save-current-buffer
(org-roam-dailies-goto-today "u")
(unless (eq original-buffer (current-buffer))
(let ((elt (org-element-context)))
(if (not (eq 'plain-list (org-element-type elt)))
(insert "\n- " link-text)
(org-down-element)
(cl-loop
for elt = (org-element-context)
while (eq 'item (org-element-type elt))
if (equal link-text (+org-element-contents elt)) return nil
do (org-forward-element)
finally (insert "- " link-text))))))))))
(add-hook 'after-save-hook #'+org-roam-updated-on-save)
I originally tried to do this using just capture templates (i.e., just an interpolated Lisp expression, no wrapper code), but I'm not sure that that's possible due to some flexibility problems with the Org-roam capture system.
One thing I'm not happy about is having to use my weird homespun +save-current-buffer macro, but the original save-current-buffer macro doesn't switch back for some reason.
I am kind of? happy about having gotten some experience with the loop macro. I'm still not sure I like it, but I understand better why it exists in a language that doesn't have other, more structure looping facilities.
The
org-roam-timestampspackage might be worth a look. It adds created/modified timestamp properties to org-roam nodes, and automatically updates these when saving the node.An interesting feature is that it can optionally keep a sequence of modification timestamps, not just the last-modified timestamp.
It doesn't actually change the SQLite schema though. All it does is update the properties in the Org file. (Org-roam considers the files to be canonical; the DB is really just a disposable index for speedy lookups.) The node table already has a properties column, so the created/modified timestamps end up buried in this.
The
org-roam-timestampspackage is a bit lacking in features, I'd say. All it does is save and update the timestamp properties for each Org-roam node. It doesn't provide any useful query functions. I've had this package installed for ages, but I don't really do anything with it. For now, it's just collecting timestamps for the sake of posterity.I have a vague idea to write some query functions, such as "what nodes did I create/modify on the same day as the current node?". The results could populate a section in the Org-roam buffer (after the backlinks), or an Org dynamic block.
I use
org-roam-timestamps; but, as you say, there are no query functions.If you have
org-roam-timestampsand just want to answer the question "which nodes did I modify on a given day", I think it would be very easy to write a function for that. But I don't think there's any harm in duplicating that data in the daily log, either.I keep a journal using org-roam-dailies. My headlines there include "Notes created" and "Notes updated". I manually create links there as I go along; it's no hardship to do that a dozen times a day, so I haven't yet automated it.